***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 09, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C4V7 A K 
.param
+vc0 = 1.846e-12	vc1 = 3.716e-10		vc2 = 1.200		vc3 = 1.603e-9		vc4 = 9.075
+tc1 = 2.051e-2		tc2 = 8.721e-3		tc3 = 1.051e-2		tc4 = 1.721e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 5.270e-16	   n = 1.001		  rs = 4.537e-1
+ibv = 1e-3		 nbv = 1.5		  bv = 4.705
+ikf = 1.4e-1
***** capacitance parameter *****
+cjo = 1.438e-10	   m = 4.304e-1		  vj = 9.843e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.148		 xti = 3
+trs1 = 1.685e-3	trs2 = 1.485e-6		tikf = 5e-3
+tbv1 = -1.445e-4	tbv2 = 6.030e-7	
.ends BZT52-C4V7
*$
